# Maintainer: Christian Hesse <mail@eworm.de>

pkgbase=lib32-libxcrypt
pkgname=(lib32-libxcrypt lib32-libxcrypt-compat)
pkgver=4.5.1
pkgrel=1
pkgdesc='Modern library for one-way hashing of passwords (32-bit)'
arch=('x86_64')
url='https://github.com/besser82/libxcrypt/'
license=('LGPL')
depends=('lib32-glibc' 'libxcrypt')
makedepends=('gcc-multilib')
validpgpkeys=('678CE3FEE430311596DB8C16F52E98007594C21D') # Björn 'besser82' Esser
source=("${url}/releases/download/v${pkgver}/libxcrypt-${pkgver}.tar.xz"{,.asc})
sha256sums=('e9b46a62397c15372935f6a75dc3929c62161f2620be7b7f57f03d69102c1a86'
            'SKIP')

build() {
  export CC="gcc -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  mkdir build-libxcrypt build-libxcrypt-compat
  cd "${srcdir}/build-libxcrypt/"
  "${srcdir}/libxcrypt-${pkgver}"/configure \
    --prefix=/usr \
    --libdir=/usr/lib32 \
    --libexecdir=/usr/lib32 \
    --disable-static \
    --enable-hashes=strong,glibc \
    --enable-obsolete-api=no \
    --disable-failure-tokens
  make 

  cd "${srcdir}/build-libxcrypt-compat/"
  "${srcdir}/libxcrypt-${pkgver}"/configure \
    --prefix=/usr \
    --libdir=/usr/lib32 \
    --libexecdir=/usr/lib32 \
    --disable-static \
    --enable-hashes=strong,glibc \
    --enable-obsolete-api=glibc \
    --disable-failure-tokens
  make 
}

package_lib32-libxcrypt() {
  cd build-libxcrypt/

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/{bin,include,share}
}

package_lib32-libxcrypt-compat() {
  pkgdesc='Modern library for one-way hashing of passwords - legacy API functions (32bit)'
  depends=('lib32-libxcrypt')
  
  cd build-libxcrypt-compat/
  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/{include,lib32/{lib*.so,pkgconfig},share}
}
